1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
|
;******************************************************************************
;* add_bitmaps.asm: SSE2 and x86 add_bitmaps
;******************************************************************************
;* Copyright (C) 2013 rcombs <rcombs@rcombs.me>
;*
;* This file is part of libass.
;*
;* Permission to use, copy, modify, and distribute this software for any
;* purpose with or without fee is hereby granted, provided that the above
;* copyright notice and this permission notice appear in all copies.
;*
;* THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
;* WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
;* MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
;* ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
;* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
;* ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
;* OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
;******************************************************************************
%include "x86/x86inc.asm"
SECTION_RODATA 32
times 32 db 0xFF
edge_mask: times 32 db 0x00
words_255: times 16 dw 0xFF
SECTION .text
;------------------------------------------------------------------------------
; BLEND_BITMAPS 1:add/sub
; void add_bitmaps(uint8_t *dst, intptr_t dst_stride,
; uint8_t *src, intptr_t src_stride,
; intptr_t height, intptr_t width);
; void sub_bitmaps(uint8_t *dst, intptr_t dst_stride,
; uint8_t *src, intptr_t src_stride,
; intptr_t height, intptr_t width);
;------------------------------------------------------------------------------
%macro BLEND_BITMAPS 1
%if ARCH_X86_64
cglobal %1_bitmaps, 6,8,3
DECLARE_REG_TMP 7
%else
cglobal %1_bitmaps, 4,7,3
DECLARE_REG_TMP 4
mov r5, r5m
%endif
lea r0, [r0 + r5]
lea r2, [r2 + r5]
neg r5
mov r6, r5
and r5, mmsize - 1
lea t0, [edge_mask]
movu m2, [t0 + r5 - mmsize]
%if !ARCH_X86_64
mov r4, r4m
%endif
imul r4, r3
add r4, r2
mov r5, r6
jmp .loop_entry
.width_loop:
p%1usb m0, m1
movu [r0 + r5 - mmsize], m0
.loop_entry:
movu m0, [r0 + r5]
movu m1, [r2 + r5]
add r5, mmsize
jnc .width_loop
pand m1, m2
p%1usb m0, m1
movu [r0 + r5 - mmsize], m0
add r0, r1
add r2, r3
mov r5, r6
cmp r2, r4
jl .loop_entry
RET
%endmacro
INIT_XMM sse2
BLEND_BITMAPS add
BLEND_BITMAPS sub
INIT_YMM avx2
BLEND_BITMAPS add
BLEND_BITMAPS sub
%if ARCH_X86_64
;------------------------------------------------------------------------------
; void mul_bitmaps( uint8_t *dst, intptr_t dst_stride,
; uint8_t *src1, intptr_t src1_stride,
; uint8_t *src2, intptr_t src2_stride,
; intptr_t width, intptr_t height );
;------------------------------------------------------------------------------
INIT_XMM
cglobal mul_bitmaps_x86, 8,12
.skip_prologue:
imul r7, r3
add r7, r2 ; last address
.height_loop:
xor r8, r8 ; x offset
.stride_loop:
movzx r9, byte [r2 + r8]
movzx r10, byte [r4 + r8]
imul r9, r10
add r9, 255
shr r9, 8
mov byte [r0 + r8], r9b
inc r8
cmp r8, r6
jl .stride_loop ; still in scan line
add r0, r1
add r2, r3
add r4, r5
cmp r2, r7
jl .height_loop
RET
INIT_XMM sse2
cglobal mul_bitmaps, 8,12
.skip_prologue:
cmp r6, 8
jl mul_bitmaps_x86.skip_prologue
imul r7, r3
add r7, r2 ; last address
pxor xmm2, xmm2
movdqa xmm3, [words_255]
mov r9, r6
and r9, -8 ; &= (~8);
.height_loop:
xor r8, r8 ; x offset
.stride_loop:
movq xmm0, [r2 + r8]
movq xmm1, [r4 + r8]
punpcklbw xmm0, xmm2
punpcklbw xmm1, xmm2
pmullw xmm0, xmm1
paddw xmm0, xmm3
psrlw xmm0, 0x08
packuswb xmm0, xmm0
movq [r0 + r8], xmm0
add r8, 8
cmp r8, r9
jl .stride_loop ; still in scan line
.stride_loop2:
cmp r8, r6
jge .finish
movzx r10, byte [r2 + r8]
movzx r11, byte [r4 + r8]
imul r10, r11
add r10, 255
shr r10, 8
mov byte [r0 + r8], r10b
inc r8
jmp .stride_loop2
.finish:
add r0, r1
add r2, r3
add r4, r5
cmp r2, r7
jl .height_loop
RET
INIT_YMM avx2
cglobal mul_bitmaps, 8,12
cmp r6, 16
jl mul_bitmaps_sse2.skip_prologue
%if mmsize == 32
vzeroupper
%endif
imul r7, r3
add r7, r2 ; last address
vpxor ymm2, ymm2
vmovdqa ymm3, [words_255]
mov r9, r6
and r9, -16 ; &= (~16);
.height_loop:
xor r8, r8 ; x offset
.stride_loop:
vmovdqu xmm0, [r2 + r8]
vpermq ymm0, ymm0, 0x10
vmovdqu xmm1, [r4 + r8]
vpermq ymm1, ymm1, 0x10
vpunpcklbw ymm0, ymm0, ymm2
vpunpcklbw ymm1, ymm1, ymm2
vpmullw ymm0, ymm0, ymm1
vpaddw ymm0, ymm0, ymm3
vpsrlw ymm0, ymm0, 0x08
vextracti128 xmm4, ymm0, 0x1
vpackuswb ymm0, ymm0, ymm4
vmovdqa [r0 + r8], xmm0
add r8, 16
cmp r8, r9
jl .stride_loop ; still in scan line
.stride_loop2:
cmp r8, r6
jge .finish
movzx r10, byte [r2 + r8]
movzx r11, byte [r4 + r8]
imul r10, r11
add r10, 255
shr r10, 8
mov byte [r0 + r8], r10b
inc r8
jmp .stride_loop2
.finish:
add r0, r1
add r2, r3
add r4, r5
cmp r2, r7
jl .height_loop
RET
%endif
|
